greeter1.ex

# before Elixir 1.18 (without defdelegate)
defmodule NameBehaviour do
  @callback name :: String.t() | :leave_me_alone
  @optional_callbacks [name: 0]
end

defmodule Greeter do
  defmacro __using__(_opts) do
    quote do
      @behaviour NameBehaviour

      def name, do: nil

      def greet do
        case name() do
          nil -> "Hello stranger"
          :leave_me_alone -> "Sorry..."
          name -> "Hello " <> name
        end
      end

      defoverridable name: 0
    end
  end
end

defmodule John do
  use Greeter

  def name do
    "John"
  end
end

defmodule Alice do
  use Greeter

  def name do
    :leave_me_alone
  end
end

defmodule Bob do
  use Greeter
end

iex> John.greet()
"Hello John"
iex> Alice.greet()
"Sorry..."
iex> Bob.greet()
"Hello stranger"

greeter2.ex

# before Elixir 1.18 (with defdelegate)
defmodule NameBehaviour do
  @callback name :: String.t() | :leave_me_alone
  @optional_callbacks [name: 0]
end

defmodule Greeter do
  defmacro __using__(_opts) do
    quote do
      @behaviour NameBehaviour

      defdelegate name, to: unquote(__MODULE__)

      def greet do
        case name() do
          nil -> "Hello stranger"
          :leave_me_alone -> "Sorry..."
          name -> "Hello " <> name
        end
      end

      defoverridable name: 0
    end
  end

  def name, do: nil
end

defmodule John do
  use Greeter

  def name do
    "John"
  end
end

defmodule Alice do
  use Greeter

  def name do
    :leave_me_alone
  end
end

defmodule Bob do
  use Greeter
end

iex> John.greet()
"Hello John"
iex> Alice.greet()
"Sorry..."
iex> Bob.greet()
"Hello stranger"

greeter3.ex

# after Elixir 1.18
defmodule NameBehaviour do
  @callback name :: String.t() | :leave_me_alone
  @optional_callbacks [name: 0]
end

defmodule Greeter do
  defmacro __using__(_opts) do
    quote do
      @behaviour NameBehaviour
    end
  end

  def greet(module) do
    if Code.ensure_loaded?(module) and function_exported?(module, :name, 0) do
      case module.name() do
        :leave_me_alone -> "Sorry..."
        name -> "Hello " <> name
      end
    else
      "Hello stranger"
    end
  end
end

defmodule John do
  use Greeter

  def name do
    "John"
  end
end

defmodule Alice do
  use Greeter

  def name do
    :leave_me_alone
  end
end

defmodule Bob do
  use Greeter
end

iex> Greeter.greet(John)
"Hello John"
iex> Greeter.greet(Alice)
"Sorry..."
iex> Greeter.greet(Bob)
"Hello stranger"