ripples

gistfile1.pde

// yikes not the prettiest code. by dw @ bees & bombs

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 120;        
float shutterAngle = .8;

boolean recording = false;

void setup_() {
  size(500, 500, P3D);
  rectMode(CENTER);
  smooth(8);
  fill(128);
  stroke(0, 128, 255);
  noStroke();
}

float x1, y1, x2, y2, tt;
int N = 100;
float l = 5;
float dd;
float h = 60;
int v = 4;

float z(float x, float y) {
  dd = .0001*(x*x+y*y);
  return h*sin(TWO_PI*t - dd)*exp(-.125*dd);
}

void draw_() {
  background(250); 
  pushMatrix();
  translate(250, 200);
  rotateX(0.66);
  beginShape(TRIANGLES);
  for (int i=-N; i<=N; i++) {
    for (int j=-N; j<=N; j++) {
      fill(28);
      if ((j+N+2)/4 % 2 == 0)
        fill(250);
      x1 = i*l; 
      x2 = (i+1)*l;
      y1 = (j+2*v*t)*l; 
      y2 = (j+1+2*v*t)*l;
      vertex(x1, y1, z(x1, y1));
      vertex(x1, y2, z(x1, y2));
      vertex(x2, y2, z(x2, y2));
      vertex(x1, y1, z(x1, y1));
      vertex(x2, y1, z(x2, y1));
      vertex(x2, y2, z(x2, y2));
    }
  }
  endShape();
  popMatrix();
}