title

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title TEH WINTESS
author Michael Fairley
homepage www.m12y.com

require_player_movement

========
OBJECTS
========

Player
White

PlayerZ
Gray

Empty
Black

Full
White

FullZ
Gray

Wall
Yellow

SqBlack
Yellow Black
00000
01110
01110
01110
00000

SqWhite
Yellow White
00000
01110
01110
01110
00000

Start
Black

End
Black

Trail
Orange

TrailZ
Orange

Background
Orange

WallOOB
Yellow

Flood
Orange
.....
.....
.....
.....
.....

FloodWhite
Orange White
.....
.....
.....
.....
.....

FloodBlack
Orange Black
.....
.....
.....
.....
.....

Lose
Red

(
.....
.....
.....
.....
.....
)

=======
LEGEND
=======

. = Wall
, = WallOOB
+ = Empty
S = Start and Player
e = End	
B = SqBlack
W = SqWhite
Z = PlayerZ

Players = Player or PlayerZ
Fulls = Full or FullZ

Walls = Wall or SqBlack or SqWhite or WallOOB
SqFloods = FloodWhite or FloodBlack
Unfloodables = Players or Fulls or WallOOB

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
End, Start, Empty
Trail, TrailZ
Players, Fulls, Walls
Lose
Flood
SqFloods

======
RULES
======

[ > Player ] -> [ > Player Trail ]
late [ Trail no Player ] -> [ Full ]

horizontal [ > Player ] [ PlayerZ ] -> [ > Player ] [ < PlayerZ ]
vertical [ > Player ] [ PlayerZ ] -> [ > Player ] [ > PlayerZ ]

[ > PlayerZ ] -> [ > PlayerZ TrailZ ]
late [ TrailZ no PlayerZ ] -> [ FullZ ]
late [ TrailZ PlayerZ ] -> cancel

late [ Player End | Wall ] -> [ Player End | Flood Wall ]

late [ Flood | no Flood no Unfloodables ] -> [ Flood | Flood ]

late [ Flood SqWhite ] -> [ Flood FloodWhite SqWhite ]
late [ Flood SqBlack ] -> [ Flood FloodBlack SqBlack ]
late [ FloodWhite | no SqFloods no Unfloodables ] -> [ FloodWhite | FloodWhite ]
late [ FloodBlack | no SqFloods no Unfloodables ] -> [ FloodBlack | FloodBlack ]
late [ FloodWhite | FloodBlack ] [ Player ] -> [ FloodWhite | FloodBlack ] [ Player Lose ]

==============
WINCONDITIONS
==============

all Players on End
no Lose

=======
LEVELS
=======
(left-right)
(basic2)

.........e.
.+++++++++.
.+.........
.+++.+++.+.
...+.+.+.+.
.+++++++.+.
.+...+...+.
.+.+++++++.
...+.+.+...
.S++.+++++.
...........

(gaps)

.....e.
.+++++.
.+B+B+.
.+++++.
.+B+W+.
,S++++.
,,.....


...e.e...
.+++++++.
.+.+...+.
.+++++++.
...+.+.+.
.+++++++.
.+.+.+.+.
.S+++++Z.
.........


...e.e...
.+++++++.
.+.+.+.+.
.+++++++.
.+.+B+B+.
.+++++++.
.+.+.+W+.
.S+++++Z.
.,.....,.


(symmetry)
(sound?)
(star)
(one wrong?)
(loltetris)
(color)