Search records in a Cookie-Jar format file. Moved to https://github.com/fabiolimace/awk-tools

cookie-jar-search-by-key.awk

#!/usr/bin/awk -f

#
# Search records in a Cookie-Jar format file
#
# If it finds the KEY in a line that starts with `%%`, it prints the corresponding records.
#
# The text in the same line as the record separator `%%` is used as a record KEY.
#
# The KEY is a regula expression.
#
# Usage:
#
#     # prints the content of "key2" record
#     cookie-jar-search-by-key.awk -v KEY="key2" example.txt
#
# Content of `example.txt`:
#
# %% key1
# value1
# %% key2
# value2
# %% key3
# value3
#
# Gist: https://gist.github.com/fabiolimace/7bc48d3b3c91a7509c746e119a89fd61
#

/^%%/ && KEY {
	if ($2 ~ KEY) {
		show=1;
		print;
	}
	else {
		show=0;
	}
	next;
}

show == 1 {
	print;
}

cookie-jar-search-by-value.awk

#!/usr/bin/awk -f

#
# Search records in a Cookie-Jar format file
#
# If it finds the VALUE in the content of records, it prints these records.
#
# The VALUE is a regula expression.
#
# Usage:
#
#     # prints the record that contains "value2"
#     cookie-jar-search-by-value.awk -v VALUE="value2" example.txt
#
# Content of `example.txt`:
#
# %% key1
# value1
# %% key2
# value2
# %% key3
# value3
#
# Gist: https://gist.github.com/fabiolimace/7bc48d3b3c91a7509c746e119a89fd61
#

function save() {
	if (buff) {
		buff = buff "\n" $0;
	} else {
		buff = $0;
	}
}

function flush() {
	if (buff) {
		print buff;
	}
	buff = NULL;
}

function empty() {
	buff = NULL;
}

$0 !~ /^%%/ && VALUE {
	if ($0 ~ VALUE) {
		show=1;
	}
	save();
}

/^%%/ {
	if (show) {
		flush();
	} else {
		empty();
	}
	show=0;
	save();
}

END {
	if (show) {
		flush();
	}
}

planets.txt

%% Mercury
Planet: Mercury
Orbital-Radius: 57,910,000 km
Diameter: 4,880 km
Eccentricity: 0.2
Mass: 3.30e23 kg
%% Venus
Planet: Venus
Orbital-Radius: 108,200,000 km
Diameter: 12,103.6 km
Eccentricity: 0.007
Mass: 4.869e24 kg
%% Earth
Planet: Earth
Orbital-Radius: 149,600,000 km
Diameter: 12,756.3 km
Eccentricity: 0.0167
Mass: 5.972e24 kg
Moons: Luna
%% Jupiter
Planet: Jupiter
Orbital-Radius: 778,000,000 km
Diameter: 142,984 km
Eccentricity: 0.0489
Mass: 1.8982e27 kg 
Moons: Callisto
Moons: Europa
Moons: Io
Moons: Ganymede

Examples:

# show the records whose keys contain "Earth"
./cookie-jar-search-by-key.awk -v KEY=Earth planets.txt

%% Earth
Planet: Earth
Orbital-Radius: 149,600,000 km
Diameter: 12,756.3 km
Eccentricity: 0.0167
Mass: 5.972e24 kg
Moons: Luna

# show the records whose contents contain "Moon"
./cookie-jar-search-by-value.awk -v VALUE=Moon planets.txt

%% Earth
Planet: Earth
Orbital-Radius: 149,600,000 km
Diameter: 12,756.3 km
Eccentricity: 0.0167
Mass: 5.972e24 kg
Moons: Luna
%% Jupiter
Planet: Jupiter
Orbital-Radius: 778,000,000 km
Diameter: 142,984 km
Eccentricity: 0.0489
Mass: 1.8982e27 kg 
Moons: Callisto
Moons: Europa
Moons: Io
Moons: Ganymede