PKGBUILD

# Maintainer: Brian Bidulock <[email protected]>
# Contributor: Jan de Groot <[email protected]>
# Contributor: Aline Freitas <[email protected]>

pkgname=polkit-git
_pkgname=polkit
pkgver=121.r10.g4e937fd
pkgrel=1
epoch=1
pkgdesc="Application development toolkit for controlling system-wide privileges"
arch=(i686 x86_64)
license=(LGPL)
url="https://www.freedesktop.org/wiki/Software/polkit/"
depends=(glib2 pam expat systemd js78)
makedepends=(intltool gtk-doc gobject-introspection git python-six meson)
checkdepends=(python-dbusmock)
backup=(etc/pam.d/polkit-1)
provides=("${_pkgname}=${pkgver%%.r*}-${pkgrel}")
conflicts=("${_pkgname}")
source=($pkgname::git+https://gitlab.freedesktop.org/polkit/polkit.git)
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags --long|sed -r 's,([^-]*-g),r\1,;s,-,.,g'
}

build() {
  cd $pkgname

  local meson_options=(
    -D examples=true
  )

  sed -i -e 's/expiration_seconds = 5 \* 60;/expiration_seconds = 8 * 60 * 60;/' src/polkitbackend/polkitbackendinteractiveauthority.c

  arch-meson $srcdir/$pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  cd $pkgname
  meson test --print-errorlogs -C build
}

package() {
  cd $pkgname

  meson install -C build --destdir "$pkgdir"

  chmod 0755 "$pkgdir/etc/polkit-1/rules.d"
  chmod 0755 "$pkgdir/usr/share/polkit-1/rules.d"

  install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf" <<END
d /etc/polkit-1/rules.d 0750 root polkitd -
d /usr/share/polkit-1/rules.d 0750 root polkitd -
END

  install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf" <<END
u polkitd 102 "PolicyKit daemon"
m polkitd proc
END
}

# vim: ts=2 sw=2 et: