Task.async vs Kernel.spawn with async tests using manual sandbox mode in Ecto.

user_test.exs

defmodule ScratchApp.UserTest do
  use ExUnit.Case, async: true

  alias ScratchApp.{Repo,User}

  setup do
    :ok = Ecto.Adapters.SQL.Sandbox.checkout(Repo)
  end

  test "it should fail and it does indeed" do
    pid = self()
    spawn(fn ->
      # To fix this test, uncomment the line below
      # Ecto.Adapters.SQL.Sandbox.allow(Repo, pid, self())
      user = Repo.insert!(%User{name: "Homer Simpson", age: 15})
      send(pid, user.id)
    end)

    receive do
      id -> assert Repo.get(User, id).age == 15
    after
      100 -> assert false
    end
  end

  test "it should fail but it does not" do
    task = Task.async(fn ->
      # It should raise DBConnection.OwnershipError exception that it cannot find ownership process for
      user = Repo.insert!(%User{name: "Homer Simpson", age: 15})
      user.id
    end)
    res = Task.await(task)

    assert Repo.get(User, res).age == 15
  end
end