Gradle init script to configure `com.github.ben-manes:gradle-versions-plugin`

dependency-updates.gradle.kts

initscript {
  repositories { gradlePluginPortal() }

  dependencies { classpath("com.github.ben-manes:gradle-versions-plugin:0.41.0") }
}

allprojects {
  apply<com.github.benmanes.gradle.versions.VersionsPlugin>()

  fun isNonStable(version: String): Boolean {
    val stableKeyword = listOf("RELEASE", "FINAL", "GA").any { version.toUpperCase().contains(it) }
    val regex = "^[0-9,.v-]+(-r)?$".toRegex()
    val isStable = stableKeyword || regex.matches(version)
    return isStable.not()
  }

  tasks.withType<com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask> {
    if (project.providers.gradleProperty("stable").forUseAtConfigurationTime().isPresent()) {
      rejectVersionIf {
        isNonStable(candidate.version) && !isNonStable(currentVersion)
      }
    }
    checkForGradleUpdate = false
    checkBuildEnvironmentConstraints = true
    outputFormatter = "json"
    outputDir = "build/dependencyUpdates"
    reportfileName = "report"
  }
}