Gradle: task 'resolveDependencies' for CI

helper.gradle

task resolveDependencies {
  setDescription "Resolves all projects dependencies from the repository."
  setGroup "Build Server"

  doLast {
    rootProject.allprojects { project ->
      project.buildscript.configurations.forEach { configuration ->
        if (configuration.canBeResolved) {
          configuration.resolve()
        }
      }

      project.configurations.forEach { configuration ->
        if (configuration.canBeResolved) {
          configuration.resolve()
        }
      }
    }
  }
}

nice task, helped me a lot! small refactoring:

    doLast {
        rootProject.allprojects { project ->
            Set<Configuration> configurations = project.buildscript.configurations + project.configurations
            configurations.findAll { c -> c.canBeResolved }
                    .forEach { c -> c.resolve() }
        }
    }

thx, very useful!
Helped me with a docker build issue throwing randomly SSL shut down incorrectly errors and also caching downloads of course

thx, code with kotlin

build.gradle.kts

task("resolveDependencies") {
    description = "Resolves all projects dependencies from the repository."
    group = "Build Server"

    doLast {
        rootProject.allprojects {
            (project.buildscript.configurations + project.configurations).forEach { configuration ->
                if (configuration.isCanBeResolved) {
                    configuration.resolve()
                }
            }
        }
    }
}