first attempt on trying to import/export existing vocabulary into/from wikibase. this query is for exporting annotated wikibase into RDF/OWL using OWL equivalentXX property

export_vocab_from_wb.rq

CONSTRUCT { 
  ?ss ?pe ?oo .
  ?ss rdfs:label ?l
}
WHERE { 
  # original statement
  ?s ?p ?o. 
  ?s rdfs:label ?l.
  
  # we know there's an equivalent property for p
  # equivalent property (P3)
  [] wikibase:directClaim ?p; wdt:P3 ?pe .
  FILTER(?pe != owl:equivalentProperty && ?pe != owl:equivalentClass && ?pe != owl:sameAs)
  
  # in addition, change ?o if there's an equivalent class of it 
  OPTIONAL{
    # equivalent class (P2)
    ?o wdt:P2 ?o_.
  }
  # replace if(bound(?o_), ?o_, ?o) with coalesce
  BIND(COALESCE(?o_, ?o) as ?oo)
  
  # in addition, change ?s if there's an equivalent class of it 
  OPTIONAL{
    # equivalent class (P2)
    ?s wdt:P2 ?s_.
  }
  OPTIONAL{
    # equivalent property (P3)
    ?s wdt:P3 ?s__ .
  }
  OPTIONAL{
    # same as (P8)
    ?s wdt:P8 ?s___ .
  }
  # replace if(bound(?s_), ?s_, ?s) with coalesce
  BIND(COALESCE(?s_, ?s__, ?s___, ?s) as ?ss)
}