Fix find_package(Curses) in CMake to work with a minimal example in C

Readme.md

Find find_package(Curses) in CMake

CMake FindCurses doesn't work for all systems. The patches added by our curses.cmake make CMake with Curses work for more systems.

https://stackoverflow.com/a/67964252/4236751

CMakeLists.txt

cmake_minimum_required(VERSION 3.18)

project(CursesDemo LANGUAGES C)

include(curses.cmake)

add_executable(test_curses test_curses.c)
target_link_libraries(test_curses PRIVATE Curses::Curses)

curses.cmake

# CMake FindCurses may not find all needed include directories and may need definitions

find_package(Curses REQUIRED)

if(NOT CURSES_HAVE_CURSES_H)
  foreach(d IN LISTS CURSES_INCLUDE_DIRS)
    find_path(curses_inc
    NAMES curses.h
    HINTS ${d}/ncurses ${d}/pdcurses
    NO_DEFAULT_PATH
    )
    if(curses_inc)
      list(APPEND CURSES_INCLUDE_DIRS ${curses_inc})
      break()
    endif()
  endforeach()
endif()

if(NOT TARGET Curses::Curses)
  add_library(Curses::Curses INTERFACE IMPORTED)
  target_link_libraries(Curses::Curses INTERFACE ${CURSES_LIBRARIES})
  target_include_directories(Curses::Curses INTERFACE ${CURSES_INCLUDE_DIRS})
  if(CURSES_HAVE_NCURSES_H OR CURSES_HAVE_NCURSES_NCURSES_H)
    # https://stackoverflow.com/a/67964252/4236751
    # avoids MinGW link failure
    target_compile_definitions(Curses::Curses INTERFACE $<$<BOOL:${MINGW}>:NCURSES_STATIC>)
  endif()
endif()

test_curses.c

#include <curses.h>

int main(void)
{
    initscr();

    printw("Hello from Curses. Press any key to continue...");

    refresh();

    // pause the screen output
    getch();

    endwin();
    return 0;
}