Building an immutable tree

immutable-tree.pl

#!/usr/bin/env perl

use v5.14;
use strict;
use warnings;
use Data::Dump 'pp';

{
    package Node;
    use Mouse;

    has 'tag' => (isa => 'Str', is => 'ro');
    has 'children' => (isa => 'ArrayRef[Node]', is => 'ro', writer => '_set_children');
    has 'parent' => (isa => 'Maybe[Node]', is => 'ro');

    sub build_tree {
        my ($class, $tag, $rest, $parent) = @_;
        my $node = Node->new(tag => $tag, parent => $parent);
        my @children;
        while (my ($k, $v) = each %$rest) {
            push @children, $class->build_tree($k, $v, $node);
        }
        $node->_set_children(\@children);
        return $node;
    }
}

pp(Node->build_tree(
    a => {
        b => {
            c => {},
        },
    }
));

__END__
do {
  my $a = bless({
    children => [
      bless({
        children => [
          bless({ children => [], parent => 'fix', tag => "c" }, "Node"),
        ],
        parent => 'fix',
        tag => "b",
      }, "Node"),
    ],
    parent => undef,
    tag => "a",
  }, "Node");
  $a->{children}[0]{children}[0]{parent} = $a->{children}[0];
  $a->{children}[0]{parent} = $a;
  $a;
}